Modul 11 (Web Server)

Web Server

Pada modul kali ini, kita akan membuat dan menguji sebuah sistem web server berbasis ESP32 yang dapat digunakan untuk menghidupkan dan mematikan LED melalui browser, menggunakan koneksi WiFi lokal.

Alat dan Bahan

• ESP32 Dev Board
• 2 LED (warna bebas, dalam laporan ini digunakan 2 warna biru)
• 2 Resistor 330Ω
• Breadboard dan Jumper
• Kabel USB (ESP32 ke laptop)
• Laptop dengan Arduino IDE
• Jaringan WiFi 2.4 GHz / Hotspot 4G (SSID & Password diketahui)

Rangkaian

• LED pertama disambungkan ke pin GPIO 26
• LED kedua disambungkan ke pin GPIO 27
• Ground terhubung ke GND ESP32 melalui resistor
• Berikut gambar rangkaiannya :

Langkah-Langkah Percobaan

1. Buka Arduino IDE

2. Pastikan board ESP32 sudah terpasang (ESP32 Dev Module)

3. Masukkan kode program berikut.

// Project Standalone Web Server

// Load Wi-Fi library
#include <WiFi.h>

// Replace with your network credentials
const char* ssid = "SS";
const char* password = "Ucando1t";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output26State = "off";
String output27State = "off";

// Assign output variables to GPIO pins
const int output26 = 26;
const int output27 = 27;

// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0; 
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output26, OUTPUT);
  pinMode(output27, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output26, LOW);
  digitalWrite(output27, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    currentTime = millis();
    previousTime = currentTime;
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected() && currentTime - previousTime <= timeoutTime) {  // loop while the client's connected
      currentTime = millis();
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();

            // turns the GPIOs on and off
            if (header.indexOf("GET /26/on") >= 0) {
              Serial.println("GPIO 26 on");
              output26State = "on";
              digitalWrite(output26, HIGH);
            } else if (header.indexOf("GET /26/off") >= 0) {
              Serial.println("GPIO 26 off");
              output26State = "off";
              digitalWrite(output26, LOW);
            } else if (header.indexOf("GET /27/on") >= 0) {
              Serial.println("GPIO 27 on");
              output27State = "on";
              digitalWrite(output27, HIGH);
            } else if (header.indexOf("GET /27/off") >= 0) {
              Serial.println("GPIO 27 off");
              output27State = "off";
              digitalWrite(output27, LOW);
            }

            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #555555;}</style></head>");

            // Web Page Heading
            client.println("<body><h1>ESP32 Web Server</h1>");

            // Display current state, and ON/OFF buttons for GPIO 26  
            client.println("<p>GPIO 26 - State " + output26State + "</p>");
            // If the output26State is off, it displays the ON button       
            if (output26State=="off") {
              client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 

            // Display current state, and ON/OFF buttons for GPIO 27  
            client.println("<p>GPIO 27 - State " + output27State + "</p>");
            // If the output27State is off, it displays the ON button       
            if (output27State=="off") {
              client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");

            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

4. Ubah SSID dan Password WiFi agar sesuai di bagian berikut.

// Replace with your network credentials
const char* ssid = "SS";
const char* password = "Ucando1t";

5. Upload program ke ESP32.

6. Buka Serial Monitor (baud 115200) untuk melihat alamat IP lokal. Berikut tampilan serial monitor jika kode berhasil.

7. Setelah IP muncul di Serial Monitor, buka browser di perangkat yang terhubung ke jaringan WiFi yang sama.

8. Masukkan IP tersebut, maka akan muncul tampilan kontrol dua LED

9. Klik tombol ON/OFF untuk GPIO26 atau GPIO27 sesuai keinginan untuk menguji web server

Hasil Percobaan

Hasil percobaan menunjukkan bahwa LED yang terhubung ke GPIO 26 dan GPIO 27 pada ESP32 dapat dikendalikan dengan baik melalui halaman web yang diakses dari browser.

Kesimpulan

Percobaan ini membuktikan bahwa ESP32 mampu berfungsi sebagai web server sederhana yang responsif dan dapat digunakan untuk mengontrol perangkat elektronik seperti LED melalui jaringan lokal. Dengan mengakses IP dari ESP32 melalui browser, pengguna dapat menyalakan atau mematikan LED secara real-time menggunakan tombol antarmuka HTML. Sistem ini merupakan dasar yang baik untuk mengembangkan proyek Internet of Things (IoT) berbasis ESP32.